Control-Car-Using-PS3-Controller/Control-Car-Using-PS3-Controller.cpp at main · JordyMail/Control-Car-Using-PS3-Controller · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

const char* ssid = "yourWifiName";  // your own WiFi
const char* password = "yourWIfiPassword";
const char* mqtt_server = "broker.emqx.io";

WiFiClient espClient;
PubSubClient client(espClient);

// Light pin
#define Green 15
#define Red 13

// Pin Motor
#define ENA 16  // Enable Motor A
#define ENB 14  // Enable Motor B
#define MOTOR_A1 5
#define MOTOR_A2 4
#define MOTOR_B1 0
#define MOTOR_B2 2

//default speed (0-1023)
int speedValue = 255;

void setup() {
    Serial.begin(115200);

    // Inisialisasi WiFi
    WiFi.begin(ssid, password);
    while (WiFi.status() != WL_CONNECTED) {
        delay(500);
        Serial.print(".");
    }
    Serial.println("\nConnected to WiFi");

    // MQTT
    client.setServer(mqtt_server, 1883);
    client.setCallback(callback);

    reconnect();

    // Setup pin Light
    pinMode(Green, OUTPUT);
    pinMode(Red, OUTPUT);

    // Setup pin motor
    pinMode(ENA, OUTPUT);
    pinMode(ENB, OUTPUT);
    pinMode(MOTOR_A1, OUTPUT);
    pinMode(MOTOR_A2, OUTPUT);
    pinMode(MOTOR_B1, OUTPUT);
    pinMode(MOTOR_B2, OUTPUT);

  //set intiial speed
 analogWrite(ENA, speedValue);
 analogWrite(ENB, speedValue);
}
void moveForward() {
    analogWrite(ENA, speedValue);
    analogWrite(ENB, speedValue);
    digitalWrite(MOTOR_A1, HIGH);
    digitalWrite(MOTOR_A2, LOW);
    digitalWrite(MOTOR_B1, HIGH);
    digitalWrite(MOTOR_B2, LOW);
}
void moveBackward() {
    analogWrite(ENA, speedValue);
    analogWrite(ENB, speedValue);
    digitalWrite(MOTOR_A1, LOW);
    digitalWrite(MOTOR_A2, HIGH);
    digitalWrite(MOTOR_B1, LOW);
    digitalWrite(MOTOR_B2, HIGH);
}
void turnLeft() {
 analogWrite(ENA, speedValue);
 analogWrite(ENB, speedValue);
 digitalWrite(MOTOR_A1, LOW);
 digitalWrite(MOTOR_A2, HIGH);
 digitalWrite(MOTOR_B1, HIGH);
 digitalWrite(MOTOR_B2, LOW);
}

void turnRight() {
    analogWrite(ENA, speedValue);
    analogWrite(ENB, speedValue);
    digitalWrite(MOTOR_A1, HIGH);
    digitalWrite(MOTOR_A2, LOW);
    digitalWrite(MOTOR_B1, LOW);
    digitalWrite(MOTOR_B2, HIGH);
}

void stopCar() {
    analogWrite(ENA, 0);
    analogWrite(ENB, 0);
    digitalWrite(MOTOR_A1, LOW);
    digitalWrite(MOTOR_A2, LOW);
    digitalWrite(MOTOR_B1, LOW);
    digitalWrite(MOTOR_B2, LOW);
}

// Callback when MQTT message is received
void callback(char* topic, byte* payload, unsigned int length) {
    String message = "";
    for (int i = 0; i < length; i++) {
        message += (char)payload[i];
    }
    Serial.println("message received: " + message);

    if (message == "forward") {
        moveForward();
        digitalWrite(Green, HIGH);
        digitalWrite(Red, LOW);
    } else if (message == "backward") {
        moveBackward();
        digitalWrite(Green, HIGH);
        digitalWrite(Red, LOW);
    } else if (message == "left") {
        turnLeft();
        digitalWrite(Green, HIGH);
        digitalWrite(Red, LOW);
    } else if (message == "right") {
        turnRight();
        digitalWrite(Green, HIGH);
        digitalWrite(Red, LOW);
    } else if (message == "stop") {
        stopCar();
        digitalWrite(Red, HIGH);
        digitalWrite(Green, LOW);
    } else if (message.startsWith("speed:")) {
        speedValue = message.substring(6).toInt();
        analogWrite(ENA, speedValue);
        analogWrite(ENB, speedValue);
        Serial.println("Speed is changed to: " + String(speedValue));
    }
}

// Function to ensure the connection to MQTT remains active
void reconnect() {
    while (!client.connected()) {
        Serial.print("Connecting to MQTT...");
        if (client.connect("mqttx_edd67096")) {
            Serial.println("Connected");
            client.subscribe("IoT/example");
        } else {
            Serial.print("Failed, rc=");
            Serial.print(client.state());
            Serial.println(" try again in 5 seconds....");
            delay(5000);
        }
    }
}

void loop() {
    if (!client.connected()) {
        reconnect();
    }
    client.loop();
}