Python: Add test for missing relative import in namespace packages

Author: tausbn

python/ql/test/experimental/import-resolution-namespace-relative/options

@@ -0,0 +1 @@
+semmle-extractor-options: -R ./pkg

python/ql/test/experimental/import-resolution-namespace-relative/pkg/caller.py

@@ -0,0 +1,5 @@
+from . import helper
+
+def use_relative():
+    tainted = source()
+    helper.process(tainted)

python/ql/test/experimental/import-resolution-namespace-relative/pkg/helper.py

@@ -0,0 +1,2 @@
+def process(value):
+    sink(value) #$ MISSING: prints=source

python/ql/test/experimental/import-resolution-namespace-relative/test.expected

@@ -0,0 +1 @@
+

python/ql/test/experimental/import-resolution-namespace-relative/test.ql

@@ -0,0 +1,35 @@
+import python
+import semmle.python.dataflow.new.DataFlow
+import semmle.python.dataflow.new.TaintTracking
+import utils.test.InlineExpectationsTest
+
+private module TestConfig implements DataFlow::ConfigSig {
+  predicate isSource(DataFlow::Node node) {
+    node.(DataFlow::CallCfgNode).getFunction().asCfgNode().(NameNode).getId() = "source"
+  }
+
+  predicate isSink(DataFlow::Node node) {
+    exists(DataFlow::CallCfgNode call |
+      call.getFunction().asCfgNode().(NameNode).getId() = "sink" and
+      node = call.getArg(0)
+    )
+  }
+}
+
+private module TestFlow = TaintTracking::Global<TestConfig>;
+
+module FlowTest implements TestSig {
+  string getARelevantTag() { result = "prints" }
+
+  predicate hasActualResult(Location location, string element, string tag, string value) {
+    exists(DataFlow::Node sink |
+      TestFlow::flow(_, sink) and
+      tag = "prints" and
+      location = sink.getLocation() and
+      value = "source" and
+      element = sink.toString()
+    )
+  }
+}
+
+import MakeTest<FlowTest>